ItGo.me Focus on IT Recommend

Home > rebol - VID layout pane supporting multiple face creations [rebol2]

rebol - VID layout pane supporting multiple face creations [rebol2]

Please consider this simple rebol2 code to illustrate my problem:

REBOL []
a: make face [
    offset: 0x0
    color: yellow
    size: 20x20
]
b: make face [
    offset: 0x0
    color: red
    size: 60x60
    pane: reduce [
        make a [offset: 0x0]
        make a [offset: 10x10]
        make a [offset: 10x20]
    ]
]
view layout [
    box 200x200 white with [
        pane: reduce [
            make b [offset: 0x30] ;; one 'instance' of b
        ]
    ]
]

The main point here is for a layout (or face) to be able to display a bunch of faces inside its pane block in such a manner that multiple creations of the same face (b in this case) should be possible. The shown code works well, and the only instance (let me call it this way) of b is displayed as it should be.

But now suppose I change the code so I have, say, 2 instances of b:

view  layout [
    box 200x200 white with [
        pane: reduce [
            make b [offset: 0x30]
            make b [offset: 0x10]
        ]
    ]
]

At this point I get the error

** Script Error: Face object reused (in more than one pane): none
** Where: view
** Near: show scr-face
if new [do-events]

From the message I presume here that face b is somehow getting reused and messing exactly what I'm trying to achieve. I've done lots of research on this and at some point I found that it is possible to get around it by cloning (using make) the face to be passed to pane; that's what I thought I was doing, but with no success at all.

Given this scenario, my question is: how can I go about to solve this? is rebol2 ok to provide this "face-instantiation" or it is best to try something else outside rebol2 (perhaps rebol3)?

Any help will be greatly appreciated.

rebol rebol2
|
  this question
asked Apr 29 '15 at 3:01 rdonatoiop 937 10 24

 | 

3 Answers
3

---Accepted---Accepted---Accepted---

As is already pointed out the problem is that a is reused, not b!

the layout function uses a field called init for handling things like this. As I understand it init is first bound to the face and then called with do after the face itself is instantiated (at least partially).

In this case I would be using the style command in layout (still partially using face object a )

view layout [
    style
        bb box 60x60
        with [
            append init [
                pane reduce [
                    make a [offset: 0x0]
                    make a [offset: 10x10]
                    make a [offset: 10x20]
               ]
            ]
        ]
    panel 200x200 white [
        at 30x0 bb
        at 0x0  bb
    ]
]

The other alternative, a bit more similar to your would be:

b: make face [
    offset: 0x0
    color: red
    size: 60x60
    init: [
        pane: reduce [
            make a [offset: 0x0]
            make a [offset: 10x10]
            make a [offset: 10x20]
        ]
    ]
]
view layout [
    box 200x200
    with [
        append init [
            pane: reduce [
                make b [ offset: 0x0 do init ]
                make b [ offset: 0x60 do init ]
            ]
        ]
    ]
 ]

Note that init is manually called within the make clause in this case. I'm not all sure why it is needed. Finally the everything could elegantly be solved with style

view layout [
    style a box yellow 20x20
    style b panel red 60x60 [
        at 0x0 a   ; we can in this style use the just defined a style
        at 10x10 a
        at 10x20 a
    ]
    at 0x0 b
    at 0x60 b
]

|
  this answer
answered Jun 14 '15 at 5:10 joing 54 4      Second approach worked best for my problem and it was straightforward/transparent for what I was intending to build upon next with this code. Thank you for posting :D –  rdonatoiop Jun 16 '15 at 19:47

 | 

Rebol2 is definitely ok to do this.

When you MAKE b second time you are using the same instance of a. That is the problem.

Recommend:rebol2 - How to run Rebol on Freya

TS). I keep getting this error: error while loading
 d libraries: libXaw.so.7: cannot open
 d object file: No such file or directory I went ahead and tried to install the missing library but to no avail. rebol rebol2
  |

You can write a function that creates necessary faces and append them to a block and return. Don't forget to create 'a (first face) every time.

Additionally, check for the iterated faces in the documentation.

Here I added an example:

REBOL []
make-pane: func [ofst [pair! block!] /local a b faces] [
    a: make face [
        offset: 0x0
        color: yellow
        size: 20x20
    ]
    faces: copy []
    either block? ofst [
        foreach o ofst [
            append faces make a [offset: o]
        ]
    ] [
        append faces make a [offset: ofst]
    ]
    b: make face [
        offset: 0x0
        color: red
        size: 60x60
        pane: faces
    ]
]

view  layout [
    box 200x200 white with [
        pane: make-pane [5x30 0x10 20x5]
    ]
]

You can change the function to get more parameters to change color and other facets as well.


|
  this answer
edited Apr 30 '15 at 10:17 answered Apr 29 '15 at 20:59 endo64 1,400 12 18      Thank you for the sample code and for the great insights, specially on iterated faces. I am currently looking into those, which I think (from what I read so far) suits me a bit better. I intend to play around a bit and then return whatever code I've written in a reply post for the sake of research sharing. Thanks again :D –  rdonatoiop Apr 30 '15 at 13:42 1   Iterated faces are a bit difficult to use and there is no enough documantation about it. But it is useful for grid / table style UI elements. –  endo64 Apr 30 '15 at 15:19      sorry, endo64; Changed my ---Accepted---Accepted---Accepted--- answer, although your answer provided me with great insights. –  rdonatoiop Jun 16 '15 at 19:50

 | 

I've said on a comment that I would get back to
  my findings and I think I got something interesting. As well pointed out by @endo64, iterated faces are tricky and perhaps not best suited to what I intended to do when I first asked the question - to achieve a simple/straigthforward way to instantiate objects thru panels.

I came up with the code bellow, which implements a kind of instantiator. It was inspired in part by the face-maker approach of @endo64 along with some tinkering with iterated faces. This instantiator has a core limitation, which is not accepting multiple types of objects being passed to the constructor to be created at same pane.

Anyway, I found it was an interesting exercise and I would like to post it here in case it could be useful to someone.

I use the same code from the question, now solving/circumventing the limitation of creating multiple b objects inside the main layout pane. a and b now hold an instantiator object, which receives an object to create inside its pane and a block of positions (pair offsets) where objects should be placed.

a: make face [
    offset: 0x0
    color: yellow
    size: 30x20
]

b: make face [
    offset: 0x0
    color: red
    size: 100x100
    inst_b: _instantiator/new reduce a [10x10 10x70 80x80 30x30] ; instantiator here  
    pane: get in inst_b 'pane_function
]

The instantiator code is:

_instantiator: make object! [
    _obj: copy []
    _offsets: copy []

    new: func [
        obj [object!] "object to create inside pane"
        offs [block!] "instances offsets"
    ][
        make self [
            _obj: obj
            _offsets: offs
        ]
    ]   
    pane_function: func [face index] [
        if integer? index [
            if index <= length? _offsets [
                _obj/offset: to-pair reduce [_offsets/:index/x _offsets/:index/y]
                _obj
            ]
        ]
    ]   
]

Code for main layout is:

_inst: _instantiator/new reduce b [0x0 50x50 130x130] ;;3 b objects are created in the positions indicated in the pairs block
_lo: layout [
    mybox: box 500x500 white with [
        offset: 0x0     
        pane: get in _inst 'pane_function
    ]   
]
view center-face _lo

|
  this answer
answered May 3 '15 at 22:22 rdonatoiop 937 10 24

 | 

Recommend:rebol2 - Is there a better way to restyle REBOL VID modal dialogs

so that they better fit with the theme of the rest of my application. The only way I've found to do this is to include my own altered version of the request function, substituting my own values into the layout in it. Is there any way to res

oriUlr:http://stackoverflow.com/questions/29933559/vid-layout-pane-supporting-multiple-face-creations-rebol2

------splitte line----------------------------